Introduction

À chaque fois que je travail en graphisme et que je dois ajouter du texte à une image, je me retrouve toujours avec le même problème: “Comment faire pour identifier rapidement la meilleure police pour mon affiche ?”

Je crois maintenant avoir finalement trouver la solution à ce problème.

Voici un script pour Microsoft Word qui permet de générer n’importe quelle exemple de texte avec toutes les polices de votre ordinateur.

Comment ça fonctionne ?

Il suffit d’ouvrir Microsoft Word et d’exécuter le script téléchargeable. Celui-ci produira un document d’environ 65 pages avec votre exemple de texte dans toutes les polices disponibles.

Fonctionnalités

La liste suivante décrit les fonctionnalités du script:

• Détecte toutes les polices installées du système.
• Donne un exemple de tous les styles pour chacune des polices soit: Normal, Italique, Gras et Gras Italique.
• Supporte vos propre exemples de texte. Si omis, le pangramme “The quick brown fox jumps over the lazy dog” est utilisé, soit l’équivalent anglophone de “Voix ambiguë d’un cœur qui, au zéphyr, préfère les jattes de kiwis”.

Limitations

Le script a quelques limitations. Celles-ci sont plus bas:

Possibilité de doublons

Certaines police ne sont pas disponibles sous certain style. Par exemple, la police Wingdings n’offre pas de style Gras (bien que le style Italique soit disponible).

Malheureusement, le script ne permet pas de détecter les styles qui ne sont pas disponibles et affichera donc plusieurs fois le même résultats.

Installation

Le script peut-être utilisé de deux façons. Les sections suivantes expliquent chacune d’elle.

Télécharger le script

Télécharger le script sur votre ordinateur en utilisant le lien suivant MsWordListInstalledFont.bas .

Procédez avec les étapes suivantes pour installer le module téléchargé:

1. Ouvrir Microsoft Word.
2. Naviguer au menu Affichage du ruban.
3. Cliquer sur le bouton Macros pour ouvrir l’éditeur de macro Microsoft Visual Basic.
4. Entrer un nom de macro bidon. Par exemple ‘police’.
5. Cliquer sur le bouton Créer.
6. Dans la fenêtre Projet, repérer les deux noeuds principaux soient Normal ou Project (Document1).
7. Pour installer le script définitivement sur l’ordinateur, cliquer avec le bouton droit de la souris sur le noeud Normal. Sinon, pour installer le script uniquement dans ce fichier Word (*.docx), cliquer sur le noeud Project (Document1).
8. Sélectionner l’option Importer un fichier…
9. Naviguer jusqu’à votre fichier téléchargé, sélectionnez-le et cliquer sur le bouton Ouvrir.
10. Un nouveau noeud nommé Modules sera créer. Sous Modules, vous pourrez apercevoir le nouveau module: ListInstalledFont.

    

11. Cliquer sur le l’icône de sauvegarde ( ) pour sauvegarder le nouveau module.
12. Fermer l’éditeur de macro Microsoft Visual Basic.

Le module est maintenant installé sur le système.

Copier coller le script

Certain fureteur ou antivirus ne permettent pas le téléchargement de module Microsoft Word (*.bas). L’option de téléchargement du module n’est donc pas possible. Dans ce cas, l’option copier-coller doit être utilisé.

Pour ce faire, copier le code suivant dans le presse-papier :

Attribute VB_Name = "ListInstalledFont"
Option Explicit

Public Sub SetupColumnsPerPage(numColumns As Integer)
    'Define numColumns columns per page
    With Selection.PageSetup.TextColumns
        .SetCount numColumns:=numColumns
        .EvenlySpaced = True
        .LineBetween = False
    End With
End Sub

Public Sub ClearDocumentContent()
    'Clear the current document
    Selection.WholeStory
    Selection.Delete Unit:=wdCharacter, Count:=1
End Sub

Public Sub SetupThinMargin()
    With Selection.PageSetup
        .LineNumbering.Active = False
        .Orientation = wdOrientPortrait
        .TopMargin = CentimetersToPoints(1.27)
        .BottomMargin = CentimetersToPoints(1.27)
        .LeftMargin = CentimetersToPoints(1.27)
        .RightMargin = CentimetersToPoints(1.27)
        .Gutter = CentimetersToPoints(0)
        .HeaderDistance = CentimetersToPoints(1.25)
        .FooterDistance = CentimetersToPoints(1.25)
        .PageWidth = CentimetersToPoints(21.59)
        .PageHeight = CentimetersToPoints(27.94)
        .FirstPageTray = wdPrinterDefaultBin
        .OtherPagesTray = wdPrinterDefaultBin
        .SectionStart = wdSectionNewPage
        .OddAndEvenPagesHeaderFooter = False
        .DifferentFirstPageHeaderFooter = False
        .VerticalAlignment = wdAlignVerticalTop
        .SuppressEndnotes = False
        .MirrorMargins = False
        .TwoPagesOnOne = False
        .BookFoldPrinting = False
        .BookFoldRevPrinting = False
        .BookFoldPrintingSheets = 1
        .GutterPos = wdGutterPosLeft
    End With
End Sub

Public Sub AddFontSample(fontIndex As Integer, fontName As String, text As String, boldFlag As Boolean, italicFlag As Boolean)
    With Selection
     'Show test string with selected font
     .Font.Name = fontName
     .Font.Size = 16
     .Font.bold = boldFlag
     .Font.italic = italicFlag
     .Font.Underline = wdUnderlineNone
     .TypeText text & Chr(11)
     
     Dim boldFontName As String
     Dim italicFontName As String
     If (boldFlag = True) Then
        boldFontName = ", Bold"
     End If
     If (italicFlag = True) Then
        italicFontName = ", Italic"
     End If
     
     'Show actual font name in document
     .Font.Name = "Times New Roman"
     .Font.Size = 9
     .Font.bold = False
     .Font.italic = False
     .Font.Underline = wdUnderlineSingle
     .TypeText "(" & fontName & boldFontName & italicFontName & ")"
     
     .InsertParagraphAfter
     .MoveDown Unit:=wdParagraph
    End With

End Sub

Public Sub ListInstalledFont()
    ClearDocumentContent
    SetupThinMargin
    SetupColumnsPerPage 2

    Application.ScreenUpdating = False

    Dim sampleText As String
    sampleText = InputBox("Enter some sample text")
    If sampleText = "" Then sampleText = "The quick brown fox jumps over the lazy dog"

    'For each installed font
    Dim fontIndex As Integer
    For fontIndex = 1 To FontNames.Count
     Dim currentFontName As String
     currentFontName = FontNames(fontIndex)
     
     'Create sample text
     AddFontSample fontIndex, currentFontName, sampleText, False, False
     AddFontSample fontIndex, currentFontName, sampleText, True, False
     AddFontSample fontIndex, currentFontName, sampleText, True, True
     AddFontSample fontIndex, currentFontName, sampleText, False, True
    Next
    
    Application.ScreenUpdating = True
End Sub

Ensuite, suivez les étapes suivante:

1. Ouvrir Microsoft Word.
2. Naviguer au menu Affichage du ruban.
3. Cliquer sur le bouton Macros pour ouvrir l’éditeur de macro Microsoft Visual Basic.
4. Entrer un nom de macro bidon. Par exemple ‘police’.
5. Cliquer sur le bouton Créer.
6. Dans la fenêtre Projet, repérer les deux noeuds principaux soient Normal ou Project (Document1).
7. Pour installer le script définitivement sur l’ordinateur, cliquer avec le bouton droit de la souris sur le noeud Normal. Sinon, pour installer le script uniquement dans ce fichier Word (*.docx), cliquer sur le noeud Project (Document1).
8. Sélectionner l’option Insertion, puis Module.
9. Un nouveau module nommé Module1 sera créé.
10. Dans la fenêtre Propriété - Module1, repérer la propriété Name du module dont la valeur est Module1.
11. Changer la valeur de la propriété pour la valeur ListInstalledFonts.
12. Coller le code dans la section de droite de l’éditeur. Le contenu du script devrait s’afficher.
13. Cliquer sur le l’icône de sauvegarde ( ) pour sauvegarder le nouveau module.
14. Fermer l’éditeur de macro Microsoft Visual Basic.

Le module est maintenant installé sur le système.

Exécuter le script

Procédez avec les étapes suivantes pour exécuter le module installé:

1. Ouvrir Microsoft Word.
2. Naviguer au menu Affichage du ruban.
3. Cliquer sur le bouton Macros. L’éditeur de macro Microsoft Visual Basic s’ouvrira.
4. Sélectionner la macro ListInstalledFonts.

   

5. Cliquer sur le bouton Exécuter pour lancer l’exécution du script.
6. La fenêtre suivante s’ouvrira:

   

7. Entrer un exemple de texte puis cliquer sur le bouton OK. Laissez le champ vide et cliquer sur le bouton OK pour utiliser le pangramme anglophone “The quick brown fox jumps over the lazy dog”.
8. Patientez environ 30 secondes pendant l’exécution du script.

Le document sera complété avec votre exemple de texte pour chacune des polices installées sur votre ordinateur.

Exemple

Après l’exécution du script, vous obtiendrez un document complet:

Licence

Le script est disponible sous la licence LGPL. Seule la version anglophone de la licence est disponible.

This library is free software; you can redistribute it and/or modify it under the terms of the GNU Lesser General Public License as published by the Free Software Foundation; either version 3.0 of the License, or (at your option) any later version.

This library is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License (LGPL-3.0) for more details.

You should have received a copy of the GNU Lesser General Public License along with this library; if not, write to the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

DISCLAIMER: This software is furnished “as is”, without technical support, and with no warranty, express or implied, as to its usefulness for any purpose.

Téléchargement

Vous pouvez télécharger le script en cliquant sur le lien de téléchargement suivant: MsWordListInstalledFont.bas